ASP 高亮顯示不區分大小寫的關鍵字

 今日，碰到一個問題：如何在網頁中高亮顯示不區分大小寫的關鍵字

例如：文本abcaBcabCaBCabcaBCa，關鍵字bc，在不區分大小寫的情況，一共有6個匹配項。

則在網頁中顯示的是abcaBcabCaBCabcaBCa。

很多人，想到是replace函數。原型為

Replace(string,find,replacewith[,start[,count[,compare]]])

string　　　　必選項，字符串表達式，包含要替代的子字符串

find　　　　　必選項，被搜索的子字符串

replacewith　必選項，用於替換的子字符串

start　　　　可選項，開始搜索子字符串的位置，默認是1

count　　　　可選項，執行子字符串替換的數目，默認是-1，表示進行所有可能的替換

compare　　可選項，比較方式，0：二進制比較；1：文本比較

雖然最後一個參數能解決不區分大小寫的問題，那麼該替換為什麼呢？

因為從示例上看，bc，Bc，bC，BC都被搜索到了，卻不能統一替換為一個文本

那麼，利用Instr這個函數來協助我們吧。

從源字符串，自左向右搜索，每找到一個匹配項。就按三步走

1、將匹配項左邊的字符串輸出

2、將匹配項套上樣式<span>後輸出

3、重復上兩步，繼續搜索右邊的字符串，直到搜索結尾



代碼如下：

public function HighLight(S,F)
dim tL,tM,tR,k
tL=""
tM=""
tR=S
k=instr(1,tR,F,1)
do while k>0
tL=tL & left(tR,k-1)
tM=mid(tR,k,len(F))
tL=tL & "<span style='color:red'>" & tM & "</span>"
tR=right(tR,Len(tR)-len(F)-k+1)
k=instr(1,tR,F,1)
loop
HighLight=tL & tR
end function

調用的時候，代碼如下：

tS="abcaBcabCaBCabcaBCa"
tF="bc"
response.Write(tS)
response.Write("<br/>")
response.Write(HighLight(tS,tF))

這樣就實現了如開頭實例的樣子

另一方面，思考是否用正則表達式更方便呢？嘗試了幾次，沒有結果。看看哪位高手用正則來解決這個問題。



寫了文章以後，網友“愚公”給出了正則表達式的解法。經測試，正確無誤。現將他的代碼貼於後。非常感謝他。

代碼

Function HighLight(S,F)
Dim regEx
Set regEx = New RegExp
regEx.IgnoreCase = True
regEx.Global = True
regEx.Pattern = "(" & F & ")"
HighLight = regEx.Replace(S,"<span style='color:red'>$1</span>")
End Function
Response.write HighLight("abcaBcabCaBCabcaBCa","bc")